Thread: Know a good syntax highlighter?

I used SciTE for a while. It uses plain text for configuration so you might like it since you don't like XML. I never wrote a syntax highlighter with it but I hacked the C++ one into a javascript one and it wasn't that bad. That was years ago though so I might not be able to help you much.

On the whole though, I think that it's usable but sucks. Quit worrying and learn to love the XML. I hope I don't get an infraction for trolling for that last sentence

I love XML, I mean it's no JSON, it's just the way that they design the XML. You can't make a grammar in XML, you can only define keywords and such.

Oh, SciTE uses SCIntilla. Uhg

NotePad++ is effing amazing.

That's also got a Scintilla backend and uses the Windows API.

Vim
Extensible syntax highlighting with a fairly easy to follow format

Here's the documentation on writing custom synatx highlighting files
http://vimdoc.sourceforge.net/htmldoc/usr_44.html

Also, here's the standard C & C++ syntax files

c.vim

Spoiler for c.vim:

Code:

" Vim syntax file
" Language:    C
" Maintainer:    Bram Moolenaar <[email protected]>
" Last Change:    2009 Jun 03

" Quit when a (custom) syntax file was already loaded
if exists("b:current_syntax")
  finish
endif

" A bunch of useful C keywords
syn keyword    cStatement    goto break return continue asm
syn keyword    cLabel        case default
syn keyword    cConditional    if else switch
syn keyword    cRepeat        while for do

syn keyword    cTodo        contained TODO FIXME XXX

" It's easy to accidentally add a space after a backslash that was intended
" for line continuation.  Some compilers allow it, which makes it
" unpredicatable and should be avoided.
syn match    cBadContinuation contained "\\\s\+$"

" cCommentGroup allows adding matches for special things in comments
syn cluster    cCommentGroup    contains=cTodo,cBadContinuation

" String and Character constants
" Highlight special characters (those which have a backslash) differently
syn match    cSpecial    display contained "\\\(x\x\+\|\o\{1,3}\|.\|$\)"
if !exists("c_no_utf")
  syn match    cSpecial    display contained "\\\(u\x\{4}\|U\x\{8}\)"
endif
if exists("c_no_cformat")
  syn region    cString        start=+L\="+ skip=+\\\\\|\\"+ end=+"+ contains=cSpecial,@Spell
  " cCppString: same as cString, but ends at end of line
  syn region    cCppString    start=+L\="+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end='$' contains=cSpecial,@Spell
else
  if !exists("c_no_c99") " ISO C99
    syn match    cFormat        display "%\(\d\+\$\)\=[-+' #0*]*\(\d*\|\*\|\*\d\+\$\)\(\.\(\d*\|\*\|\*\d\+\$\)\)\=\([hlLjzt]\|ll\|hh\)\=\([aAbdiuoxXDOUfFeEgGcCsSpn]\|\[\^\=.[^]]*\]\)" contained
  else
    syn match    cFormat        display "%\(\d\+\$\)\=[-+' #0*]*\(\d*\|\*\|\*\d\+\$\)\(\.\(\d*\|\*\|\*\d\+\$\)\)\=\([hlL]\|ll\)\=\([bdiuoxXDOUfeEgGcCsSpn]\|\[\^\=.[^]]*\]\)" contained
  endif
  syn match    cFormat        display "%%" contained
  syn region    cString        start=+L\="+ skip=+\\\\\|\\"+ end=+"+ contains=cSpecial,cFormat,@Spell
  " cCppString: same as cString, but ends at end of line
  syn region    cCppString    start=+L\="+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end='$' contains=cSpecial,cFormat,@Spell
endif

syn match    cCharacter    "L\='[^\\]'"
syn match    cCharacter    "L'[^']*'" contains=cSpecial
if exists("c_gnu")
  syn match    cSpecialError    "L\='\\[^'\"?\\abefnrtv]'"
  syn match    cSpecialCharacter "L\='\\['\"?\\abefnrtv]'"
else
  syn match    cSpecialError    "L\='\\[^'\"?\\abfnrtv]'"
  syn match    cSpecialCharacter "L\='\\['\"?\\abfnrtv]'"
endif
syn match    cSpecialCharacter display "L\='\\\o\{1,3}'"
syn match    cSpecialCharacter display "'\\x\x\{1,2}'"
syn match    cSpecialCharacter display "L'\\x\x\+'"

"when wanted, highlight trailing white space
if exists("c_space_errors")
  if !exists("c_no_trail_space_error")
    syn match    cSpaceError    display excludenl "\s\+$"
  endif
  if !exists("c_no_tab_space_error")
    syn match    cSpaceError    display " \+\t"me=e-1
  endif
endif

" This should be before cErrInParen to avoid problems with #define ({ xxx })
if exists("c_curly_error")
  syntax match cCurlyError "}"
  syntax region    cBlock        start="{" end="}" contains=ALLBUT,cCurlyError,@cParenGroup,cErrInParen,cCppParen,cErrInBracket,cCppBracket,cCppString,@Spell fold
else
  syntax region    cBlock        start="{" end="}" transparent fold
endif

"catch errors caused by wrong parenthesis and brackets
" also accept <% for {, %> for }, <: for [ and :> for ] (C99)
" But avoid matching <::.
syn cluster    cParenGroup    contains=cParenError,cIncluded,cSpecial,cCommentSkip,cCommentString,cComment2String,@cCommentGroup,cCommentStartError,cUserCont,cUserLabel,cBitField,cOctalZero,cCppOut,cCppOut2,cCppSkip,cFormat,cNumber,cFloat,cOctal,cOctalError,cNumbersCom
if exists("c_no_curly_error")
  syn region    cParen        transparent start='(' end=')' contains=ALLBUT,@cParenGroup,cCppParen,cCppString,@Spell
  " cCppParen: same as cParen but ends at end-of-line; used in cDefine
  syn region    cCppParen    transparent start='(' skip='\\$' excludenl end=')' end='$' contained contains=ALLBUT,@cParenGroup,cParen,cString,@Spell
  syn match    cParenError    display ")"
  syn match    cErrInParen    display contained "^[{}]\|^<%\|^%>"
elseif exists("c_no_bracket_error")
  syn region    cParen        transparent start='(' end=')' contains=ALLBUT,@cParenGroup,cCppParen,cCppString,@Spell
  " cCppParen: same as cParen but ends at end-of-line; used in cDefine
  syn region    cCppParen    transparent start='(' skip='\\$' excludenl end=')' end='$' contained contains=ALLBUT,@cParenGroup,cParen,cString,@Spell
  syn match    cParenError    display ")"
  syn match    cErrInParen    display contained "[{}]\|<%\|%>"
else
  syn region    cParen        transparent start='(' end=')' contains=ALLBUT,@cParenGroup,cCppParen,cErrInBracket,cCppBracket,cCppString,@Spell
  " cCppParen: same as cParen but ends at end-of-line; used in cDefine
  syn region    cCppParen    transparent start='(' skip='\\$' excludenl end=')' end='$' contained contains=ALLBUT,@cParenGroup,cErrInBracket,cParen,cBracket,cString,@Spell
  syn match    cParenError    display "[\])]"
  syn match    cErrInParen    display contained "[\]{}]\|<%\|%>"
  syn region    cBracket    transparent start='\[\|<::\@!' end=']\|:>' contains=ALLBUT,@cParenGroup,cErrInParen,cCppParen,cCppBracket,cCppString,@Spell
  " cCppBracket: same as cParen but ends at end-of-line; used in cDefine
  syn region    cCppBracket    transparent start='\[\|<::\@!' skip='\\$' excludenl end=']\|:>' end='$' contained contains=ALLBUT,@cParenGroup,cErrInParen,cParen,cBracket,cString,@Spell
  syn match    cErrInBracket    display contained "[);{}]\|<%\|%>"
endif

"integer number, or floating point number without a dot and with "f".
syn case ignore
syn match    cNumbers    display transparent "\<\d\|\.\d" contains=cNumber,cFloat,cOctalError,cOctal
" Same, but without octal error (for comments)
syn match    cNumbersCom    display contained transparent "\<\d\|\.\d" contains=cNumber,cFloat,cOctal
syn match    cNumber        display contained "\d\+\(u\=l\{0,2}\|ll\=u\)\>"
"hex number
syn match    cNumber        display contained "0x\x\+\(u\=l\{0,2}\|ll\=u\)\>"
" Flag the first zero of an octal number as something special
syn match    cOctal        display contained "0\o\+\(u\=l\{0,2}\|ll\=u\)\>" contains=cOctalZero
syn match    cOctalZero    display contained "\<0"
syn match    cFloat        display contained "\d\+f"
"floating point number, with dot, optional exponent
syn match    cFloat        display contained "\d\+\.\d*\(e[-+]\=\d\+\)\=[fl]\="
"floating point number, starting with a dot, optional exponent
syn match    cFloat        display contained "\.\d\+\(e[-+]\=\d\+\)\=[fl]\=\>"
"floating point number, without dot, with exponent
syn match    cFloat        display contained "\d\+e[-+]\=\d\+[fl]\=\>"
if !exists("c_no_c99")
  "hexadecimal floating point number, optional leading digits, with dot, with exponent
  syn match    cFloat        display contained "0x\x*\.\x\+p[-+]\=\d\+[fl]\=\>"
  "hexadecimal floating point number, with leading digits, optional dot, with exponent
  syn match    cFloat        display contained "0x\x\+\.\=p[-+]\=\d\+[fl]\=\>"
endif

" flag an octal number with wrong digits
syn match    cOctalError    display contained "0\o*[89]\d*"
syn case match

if exists("c_comment_strings")
  " A comment can contain cString, cCharacter and cNumber.
  " But a "*/" inside a cString in a cComment DOES end the comment!  So we
  " need to use a special type of cString: cCommentString, which also ends on
  " "*/", and sees a "*" at the start of the line as comment again.
  " Unfortunately this doesn't very well work for // type of comments :-(
  syntax match    cCommentSkip    contained "^\s*\*\($\|\s\+\)"
  syntax region cCommentString    contained start=+L\=\\\@<!"+ skip=+\\\\\|\\"+ end=+"+ end=+\*/+me=s-1 contains=cSpecial,cCommentSkip
  syntax region cComment2String    contained start=+L\=\\\@<!"+ skip=+\\\\\|\\"+ end=+"+ end="$" contains=cSpecial
  syntax region  cCommentL    start="//" skip="\\$" end="$" keepend contains=@cCommentGroup,cComment2String,cCharacter,cNumbersCom,cSpaceError,@Spell
  if exists("c_no_comment_fold")
    " Use "extend" here to have preprocessor lines not terminate halfway a
    " comment.
    syntax region cComment    matchgroup=cCommentStart start="/\*" end="\*/" contains=@cCommentGroup,cCommentStartError,cCommentString,cCharacter,cNumbersCom,cSpaceError,@Spell extend
  else
    syntax region cComment    matchgroup=cCommentStart start="/\*" end="\*/" contains=@cCommentGroup,cCommentStartError,cCommentString,cCharacter,cNumbersCom,cSpaceError,@Spell fold extend
  endif
else
  syn region    cCommentL    start="//" skip="\\$" end="$" keepend contains=@cCommentGroup,cSpaceError,@Spell
  if exists("c_no_comment_fold")
    syn region    cComment    matchgroup=cCommentStart start="/\*" end="\*/" contains=@cCommentGroup,cCommentStartError,cSpaceError,@Spell extend
  else
    syn region    cComment    matchgroup=cCommentStart start="/\*" end="\*/" contains=@cCommentGroup,cCommentStartError,cSpaceError,@Spell fold extend
  endif
endif
" keep a // comment separately, it terminates a preproc. conditional
syntax match    cCommentError    display "\*/"
syntax match    cCommentStartError display "/\*"me=e-1 contained

syn keyword    cOperator    sizeof
if exists("c_gnu")
  syn keyword    cStatement    __asm__
  syn keyword    cOperator    typeof __real__ __imag__
endif
syn keyword    cType        int long short char void
syn keyword    cType        signed unsigned float double
if !exists("c_no_ansi") || exists("c_ansi_typedefs")
  syn keyword   cType        size_t ssize_t off_t wchar_t ptrdiff_t sig_atomic_t fpos_t
  syn keyword   cType        clock_t time_t va_list jmp_buf FILE DIR div_t ldiv_t
  syn keyword   cType        mbstate_t wctrans_t wint_t wctype_t
endif
if !exists("c_no_c99") " ISO C99
  syn keyword    cType        bool complex
  syn keyword    cType        int8_t int16_t int32_t int64_t
  syn keyword    cType        uint8_t uint16_t uint32_t uint64_t
  syn keyword    cType        int_least8_t int_least16_t int_least32_t int_least64_t
  syn keyword    cType        uint_least8_t uint_least16_t uint_least32_t uint_least64_t
  syn keyword    cType        int_fast8_t int_fast16_t int_fast32_t int_fast64_t
  syn keyword    cType        uint_fast8_t uint_fast16_t uint_fast32_t uint_fast64_t
  syn keyword    cType        intptr_t uintptr_t
  syn keyword    cType        intmax_t uintmax_t
endif
if exists("c_gnu")
  syn keyword    cType        __label__ __complex__ __volatile__
endif

syn keyword    cStructure    struct union enum typedef
syn keyword    cStorageClass    static register auto volatile extern const
if exists("c_gnu")
  syn keyword    cStorageClass    inline __attribute__
endif
if !exists("c_no_c99")
  syn keyword    cStorageClass    inline restrict
endif

if !exists("c_no_ansi") || exists("c_ansi_constants") || exists("c_gnu")
  if exists("c_gnu")
    syn keyword cConstant __GNUC__ __FUNCTION__ __PRETTY_FUNCTION__ __func__
  endif
  syn keyword cConstant __LINE__ __FILE__ __DATE__ __TIME__ __STDC__
  syn keyword cConstant __STDC_VERSION__
  syn keyword cConstant CHAR_BIT MB_LEN_MAX MB_CUR_MAX
  syn keyword cConstant UCHAR_MAX UINT_MAX ULONG_MAX USHRT_MAX
  syn keyword cConstant CHAR_MIN INT_MIN LONG_MIN SHRT_MIN
  syn keyword cConstant CHAR_MAX INT_MAX LONG_MAX SHRT_MAX
  syn keyword cConstant SCHAR_MIN SINT_MIN SLONG_MIN SSHRT_MIN
  syn keyword cConstant SCHAR_MAX SINT_MAX SLONG_MAX SSHRT_MAX
  if !exists("c_no_c99")
    syn keyword cConstant __func__
    syn keyword cConstant LLONG_MIN LLONG_MAX ULLONG_MAX
    syn keyword cConstant INT8_MIN INT16_MIN INT32_MIN INT64_MIN
    syn keyword cConstant INT8_MAX INT16_MAX INT32_MAX INT64_MAX
    syn keyword cConstant UINT8_MAX UINT16_MAX UINT32_MAX UINT64_MAX
    syn keyword cConstant INT_LEAST8_MIN INT_LEAST16_MIN INT_LEAST32_MIN INT_LEAST64_MIN
    syn keyword cConstant INT_LEAST8_MAX INT_LEAST16_MAX INT_LEAST32_MAX INT_LEAST64_MAX
    syn keyword cConstant UINT_LEAST8_MAX UINT_LEAST16_MAX UINT_LEAST32_MAX UINT_LEAST64_MAX
    syn keyword cConstant INT_FAST8_MIN INT_FAST16_MIN INT_FAST32_MIN INT_FAST64_MIN
    syn keyword cConstant INT_FAST8_MAX INT_FAST16_MAX INT_FAST32_MAX INT_FAST64_MAX
    syn keyword cConstant UINT_FAST8_MAX UINT_FAST16_MAX UINT_FAST32_MAX UINT_FAST64_MAX
    syn keyword cConstant INTPTR_MIN INTPTR_MAX UINTPTR_MAX
    syn keyword cConstant INTMAX_MIN INTMAX_MAX UINTMAX_MAX
    syn keyword cConstant PTRDIFF_MIN PTRDIFF_MAX SIG_ATOMIC_MIN SIG_ATOMIC_MAX
    syn keyword cConstant SIZE_MAX WCHAR_MIN WCHAR_MAX WINT_MIN WINT_MAX
  endif
  syn keyword cConstant FLT_RADIX FLT_ROUNDS
  syn keyword cConstant FLT_DIG FLT_MANT_DIG FLT_EPSILON
  syn keyword cConstant DBL_DIG DBL_MANT_DIG DBL_EPSILON
  syn keyword cConstant LDBL_DIG LDBL_MANT_DIG LDBL_EPSILON
  syn keyword cConstant FLT_MIN FLT_MAX FLT_MIN_EXP FLT_MAX_EXP
  syn keyword cConstant FLT_MIN_10_EXP FLT_MAX_10_EXP
  syn keyword cConstant DBL_MIN DBL_MAX DBL_MIN_EXP DBL_MAX_EXP
  syn keyword cConstant DBL_MIN_10_EXP DBL_MAX_10_EXP
  syn keyword cConstant LDBL_MIN LDBL_MAX LDBL_MIN_EXP LDBL_MAX_EXP
  syn keyword cConstant LDBL_MIN_10_EXP LDBL_MAX_10_EXP
  syn keyword cConstant HUGE_VAL CLOCKS_PER_SEC NULL
  syn keyword cConstant LC_ALL LC_COLLATE LC_CTYPE LC_MONETARY
  syn keyword cConstant LC_NUMERIC LC_TIME
  syn keyword cConstant SIG_DFL SIG_ERR SIG_IGN
  syn keyword cConstant SIGABRT SIGFPE SIGILL SIGHUP SIGINT SIGSEGV SIGTERM
  " Add POSIX signals as well...
  syn keyword cConstant SIGABRT SIGALRM SIGCHLD SIGCONT SIGFPE SIGHUP
  syn keyword cConstant SIGILL SIGINT SIGKILL SIGPIPE SIGQUIT SIGSEGV
  syn keyword cConstant SIGSTOP SIGTERM SIGTRAP SIGTSTP SIGTTIN SIGTTOU
  syn keyword cConstant SIGUSR1 SIGUSR2
  syn keyword cConstant _IOFBF _IOLBF _IONBF BUFSIZ EOF WEOF
  syn keyword cConstant FOPEN_MAX FILENAME_MAX L_tmpnam
  syn keyword cConstant SEEK_CUR SEEK_END SEEK_SET
  syn keyword cConstant TMP_MAX stderr stdin stdout
  syn keyword cConstant EXIT_FAILURE EXIT_SUCCESS RAND_MAX
  " Add POSIX errors as well
  syn keyword cConstant E2BIG EACCES EAGAIN EBADF EBADMSG EBUSY
  syn keyword cConstant ECANCELED ECHILD EDEADLK EDOM EEXIST EFAULT
  syn keyword cConstant EFBIG EILSEQ EINPROGRESS EINTR EINVAL EIO EISDIR
  syn keyword cConstant EMFILE EMLINK EMSGSIZE ENAMETOOLONG ENFILE ENODEV
  syn keyword cConstant ENOENT ENOEXEC ENOLCK ENOMEM ENOSPC ENOSYS
  syn keyword cConstant ENOTDIR ENOTEMPTY ENOTSUP ENOTTY ENXIO EPERM
  syn keyword cConstant EPIPE ERANGE EROFS ESPIPE ESRCH ETIMEDOUT EXDEV
  " math.h
  syn keyword cConstant M_E M_LOG2E M_LOG10E M_LN2 M_LN10 M_PI M_PI_2 M_PI_4
  syn keyword cConstant M_1_PI M_2_PI M_2_SQRTPI M_SQRT2 M_SQRT1_2
endif
if !exists("c_no_c99") " ISO C99
  syn keyword cConstant true false
endif

" Accept %: for # (C99)
syn region    cPreCondit    start="^\s*\(%:\|#\)\s*\(if\|ifdef\|ifndef\|elif\)\>" skip="\\$" end="$" end="//"me=s-1 contains=cComment,cCppString,cCharacter,cCppParen,cParenError,cNumbers,cCommentError,cSpaceError
syn match    cPreCondit    display "^\s*\(%:\|#\)\s*\(else\|endif\)\>"
if !exists("c_no_if0")
  if !exists("c_no_if0_fold")
    syn region    cCppOut        start="^\s*\(%:\|#\)\s*if\s\+0\+\>" end=".\@=\|$" contains=cCppOut2 fold
  else
    syn region    cCppOut        start="^\s*\(%:\|#\)\s*if\s\+0\+\>" end=".\@=\|$" contains=cCppOut2
  endif
  syn region    cCppOut2    contained start="0" end="^\s*\(%:\|#\)\s*\(endif\>\|else\>\|elif\>\)" contains=cSpaceError,cCppSkip
  syn region    cCppSkip    contained start="^\s*\(%:\|#\)\s*\(if\>\|ifdef\>\|ifndef\>\)" skip="\\$" end="^\s*\(%:\|#\)\s*endif\>" contains=cSpaceError,cCppSkip
endif
syn region    cIncluded    display contained start=+"+ skip=+\\\\\|\\"+ end=+"+
syn match    cIncluded    display contained "<[^>]*>"
syn match    cInclude    display "^\s*\(%:\|#\)\s*include\>\s*["<]" contains=cIncluded
"syn match cLineSkip    "\\$"
syn cluster    cPreProcGroup    contains=cPreCondit,cIncluded,cInclude,cDefine,cErrInParen,cErrInBracket,cUserLabel,cSpecial,cOctalZero,cCppOut,cCppOut2,cCppSkip,cFormat,cNumber,cFloat,cOctal,cOctalError,cNumbersCom,cString,cCommentSkip,cCommentString,cComment2String,@cCommentGroup,cCommentStartError,cParen,cBracket,cMulti
syn region    cDefine        start="^\s*\(%:\|#\)\s*\(define\|undef\)\>" skip="\\$" end="$" end="//"me=s-1 keepend contains=ALLBUT,@cPreProcGroup,@Spell
syn region    cPreProc    start="^\s*\(%:\|#\)\s*\(pragma\>\|line\>\|warning\>\|warn\>\|error\>\)" skip="\\$" end="$" keepend contains=ALLBUT,@cPreProcGroup,@Spell

" Highlight User Labels
syn cluster    cMultiGroup    contains=cIncluded,cSpecial,cCommentSkip,cCommentString,cComment2String,@cCommentGroup,cCommentStartError,cUserCont,cUserLabel,cBitField,cOctalZero,cCppOut,cCppOut2,cCppSkip,cFormat,cNumber,cFloat,cOctal,cOctalError,cNumbersCom,cCppParen,cCppBracket,cCppString
syn region    cMulti        transparent start='?' skip='::' end=':' contains=ALLBUT,@cMultiGroup,@Spell
" Avoid matching foo::bar() in C++ by requiring that the next char is not ':'
syn cluster    cLabelGroup    contains=cUserLabel
syn match    cUserCont    display "^\s*\I\i*\s*:$" contains=@cLabelGroup
syn match    cUserCont    display ";\s*\I\i*\s*:$" contains=@cLabelGroup
syn match    cUserCont    display "^\s*\I\i*\s*:[^:]"me=e-1 contains=@cLabelGroup
syn match    cUserCont    display ";\s*\I\i*\s*:[^:]"me=e-1 contains=@cLabelGroup

syn match    cUserLabel    display "\I\i*" contained

" Avoid recognizing most bitfields as labels
syn match    cBitField    display "^\s*\I\i*\s*:\s*[1-9]"me=e-1 contains=cType
syn match    cBitField    display ";\s*\I\i*\s*:\s*[1-9]"me=e-1 contains=cType

if exists("c_minlines")
  let b:c_minlines = c_minlines
else
  if !exists("c_no_if0")
    let b:c_minlines = 50    " #if 0 constructs can be long
  else
    let b:c_minlines = 15    " mostly for () constructs
  endif
endif
if exists("c_curly_error")
  syn sync fromstart
else
  exec "syn sync ccomment cComment minlines=" . b:c_minlines
endif

" Define the default highlighting.
" Only used when an item doesn't have highlighting yet
hi def link cFormat        cSpecial
hi def link cCppString        cString
hi def link cCommentL        cComment
hi def link cCommentStart    cComment
hi def link cLabel        Label
hi def link cUserLabel        Label
hi def link cConditional    Conditional
hi def link cRepeat        Repeat
hi def link cCharacter        Character
hi def link cSpecialCharacter    cSpecial
hi def link cNumber        Number
hi def link cOctal        Number
hi def link cOctalZero        PreProc     " link this to Error if you want
hi def link cFloat        Float
hi def link cOctalError        cError
hi def link cParenError        cError
hi def link cErrInParen        cError
hi def link cErrInBracket    cError
hi def link cCommentError    cError
hi def link cCommentStartError    cError
hi def link cSpaceError        cError
hi def link cSpecialError    cError
hi def link cCurlyError        cError
hi def link cOperator        Operator
hi def link cStructure        Structure
hi def link cStorageClass    StorageClass
hi def link cInclude        Include
hi def link cPreProc        PreProc
hi def link cDefine        Macro
hi def link cIncluded        cString
hi def link cError        Error
hi def link cStatement        Statement
hi def link cPreCondit        PreCondit
hi def link cType        Type
hi def link cConstant        Constant
hi def link cCommentString    cString
hi def link cComment2String    cString
hi def link cCommentSkip    cComment
hi def link cString        String
hi def link cComment        Comment
hi def link cSpecial        SpecialChar
hi def link cTodo        Todo
hi def link cBadContinuation    Error
hi def link cCppSkip        cCppOut
hi def link cCppOut2        cCppOut
hi def link cCppOut        Comment

let b:current_syntax = "c"

" vim: ts=8

cpp.vim

Spoiler for cpp.vim:

Code:

" Vim syntax file
" Language:    C++
" Maintainer:    Ken Shan <[email protected]>
" Last Change:    2002 Jul 15

" For version 5.x: Clear all syntax items
" For version 6.x: Quit when a syntax file was already loaded
if version < 600
  syntax clear
elseif exists("b:current_syntax")
  finish
endif

" Read the C syntax to start with
if version < 600
  so <sfile>:p:h/c.vim
else
  runtime! syntax/c.vim
  unlet b:current_syntax
endif

" C++ extentions
syn keyword cppStatement    new delete this friend using
syn keyword cppAccess        public protected private
syn keyword cppType        inline virtual explicit export bool wchar_t
syn keyword cppExceptions    throw try catch
syn keyword cppOperator        operator typeid
syn keyword cppOperator        and bitor or xor compl bitand and_eq or_eq xor_eq not not_eq
syn match cppCast        "\<\(const\|static\|dynamic\|reinterpret\)_cast\s*<"me=e-1
syn match cppCast        "\<\(const\|static\|dynamic\|reinterpret\)_cast\s*$"
syn keyword cppStorageClass    mutable
syn keyword cppStructure    class typename template namespace
syn keyword cppNumber        NPOS
syn keyword cppBoolean        true false

" The minimum and maximum operators in GNU C++
syn match cppMinMax "[<>]?"

" Default highlighting
if version >= 508 || !exists("did_cpp_syntax_inits")
  if version < 508
    let did_cpp_syntax_inits = 1
    command -nargs=+ HiLink hi link <args>
  else
    command -nargs=+ HiLink hi def link <args>
  endif
  HiLink cppAccess        cppStatement
  HiLink cppCast        cppStatement
  HiLink cppExceptions        Exception
  HiLink cppOperator        Operator
  HiLink cppStatement        Statement
  HiLink cppType        Type
  HiLink cppStorageClass    StorageClass
  HiLink cppStructure        Structure
  HiLink cppNumber        Number
  HiLink cppBoolean        Boolean
  delcommand HiLink
endif

let b:current_syntax = "cpp"

" vim: ts=8

Excellent, I love vim Now that's a grammar.

I can never make up my mind which code editor to use, so I have like half a dozen I switch between, and more installed. Notepad++, PSPad, Komodo Edit, gVim, Emacs, HTML-Kit, Aptana Studio, and Screem and Bluefish in Ubuntu. In addition to gedit, obviously.

I doubt this will help you, just thought I'd provide more options. I'm still trying to get the hang of gVim and Emacs. I'm used to Notepad derivatives.

I'm a big vi (well, vim) supporter
As far as technical text-editors go, you can't get much more capable, or more extendable.

Console based, so you're not hampered by a GUI
(think ssh to a server half-way round the world)

The standard *nix job controls give you access to multiple instances, allowing editing of any number of files simultaneously

Coupled with screen, you can detach and re-attach console sessions between different systems / across local reboots, etc.

GUI editors have their place, but can't hope to compete with something like vim

+1 for vim.

but the more important question....

Indentation - tabs or spaces?

Tabs. Definitely tabs. For several reasons, most of which probably wouldn't make any sense if I tried to explain them, but still.

Personally I only use three editors with syntax highlighting: Notepad++, TextPad and Kwrite. Vim is too... advanced, and thus difficult. If I need syntax highlighting on a remote SSH-server, I'd rather mount the folder and use a local editor.

Originally Posted by Man of Steel

Tabs. Definitely tabs. For several reasons, most of which probably wouldn't make any sense if I tried to explain them, but still.

Defiantly.

Originally Posted by Ynot

but the more important question....

Indentation - tabs or spaces?

Depends on what you mean, I like pressing the tab key, but having the editor insert spaces instead of \t.

Spaces.

Though really, the IDEAL way would be, you configure your source control client how YOU want to download your source, and it handles the conversion for you, so your code is always in the format you want, and it doesn't matter what other people do.

I personally have been using a combo of Notepad++ and Editra. Editra is technically still in Beta, but it's so far worked very well for my (relatively low) needs.

How easy is it to write a syntax grammar? I'm not going to use it for a preexisting language, I want it for LiveScript, my company's internal scripting language.